Arduino an E-Ink-Display anschließen

In diesem Tutorial lernst du, wie man ein dreifarbiges E-Ink-Display mit einem Arduino oder ESP32 verbindet.

E-Ink oder elektronische Tinte (E-Paper) ist eine Display-Technologie, die das Aussehen von Tinte auf Papier nachahmt. Sie verwendet winzige Mikrokapseln, die mit farbigen Partikeln gefüllt sind. Wenn ein elektrisches Feld angelegt wird, bewegen sich die Partikel an die Oberfläche und erzeugen Text und Bilder.

E-Paper bietet mehrere Vorteile. Der geringe Stromverbrauch ermöglicht es Geräten, wochen- oder monatelang mit einer einzigen Ladung zu laufen. Das Display ahmt traditionelles Papier nach, bietet exzellente Lesbarkeit bei hellem Sonnenlicht und weite Betrachtungswinkel ohne Blendung. Außerdem ist E-Paper dünn und leicht. Allerdings hat E-Paper eine langsame Aktualisierung, eine begrenzte Farbpalette und ist vergleichsweise teuer.

Benötigte Bauteile

Du benötigst ein E-Paper-Display, und für dieses Tutorial habe ich ein dreifarbiges 2,9-Zoll-Display mit einer Auflösung von 296×128 Pixeln ausgewählt. Du kannst aber auch ein monochromes E-Paper mit einer anderen Größe verwenden.

Wir verbinden das E-Paper mit einem Arduino und einem ESP32. Praktisch jedes Arduino- oder ESP32-Modell funktioniert, aber der ESP32 ist die bessere Wahl. Der unten aufgeführte ESP32 lite ist besonders geeignet, da er eine Batterieschnittstelle hat und E-Paper ideal für batteriebetriebene Projekte sind.

Makerguides is a participant in affiliate advertising programs designed to provide a means for sites to earn advertising fees by linking to Amazon, AliExpress, Elecrow, and other sites. As an Affiliate we may earn from qualifying purchases.

Grundlagen von E-Paper-Displays

Die E-Paper-Technologie basiert auf der Microcapsule Electrophoretic Display (EPD)-Technologie. Das E-Paper besteht aus einer transparenten leitfähigen Polymer-Schicht als Frontelektrode und Millionen von Mikrokapseln, jede etwa so groß wie ein menschliches Haar, eingebettet in ein Polymermaterial. Diese Mikrokapseln enthalten farbige Partikel oder Pigmente (schwarz, weiß, …) in einer transparenten Flüssigkeit. Das E-Paper wird dann auf ein Substrat laminiert, das als untere Elektrode dient.

e-Paper System — E-Paper-System (source)

Die untere Elektrode ist typischerweise in Segmente oder Pixel unterteilt, die eine unabhängige Steuerung der Spannung auf jedem Segment erlauben. Dadurch kann das Display verschiedene Bilder darstellen. Sobald ein Bild erzeugt ist, kann die Spannung entfernt werden, und die Partikel bleiben in ihrer Position. Diese Eigenschaft ermöglicht es dem E-Paper, ein statisches Bild ohne Stromverbrauch anzuzeigen.

Zweipigment-Tinten-System

In einem Zweipigment-Elektro-Tinten-System enthält jede Mikrokapsel negativ geladene weiße Partikel und positiv geladene schwarze Partikel, die in einer klaren Flüssigkeit schweben. Wenn ein elektrisches Feld angelegt wird, wandern die entsprechenden Partikel je nach Polung an die Oberfläche der Mikrokapsel. Dadurch erscheint die Oberfläche an dieser Stelle entweder weiß oder schwarz.

Two Pigment System — Zweipigment-System (source)

Durch die Steuerung der elektrischen Felder an jeder Mikrokapsel kann das Display verschiedene Graustufen anzeigen, allerdings unterstützen die meisten monochromen E-Paper nur Schwarz und Weiß.

Dreipigment-Tinten-System

Ein Dreipigment-Elektro-Tinten-System erweitert das Zweipigment-System um eine zusätzliche Farbe. In diesem System enthalten die Mikrokapseln oder Mikrotassen negativ geladene weiße Partikel, positiv geladene schwarze Partikel und eine dritte Gruppe positiv geladener Pigmente, typischerweise Rot oder Gelb.

Three Pigment System — Dreipigment-System (source)

Wenn ein elektrisches Feld angelegt wird, reagieren die Partikel entsprechend ihrer Ladung. Beispielsweise bewirkt ein negatives elektrisches Feld, dass die positiv geladenen roten Partikel an die Oberfläche steigen. Eine geteilte Ladung bringt die schwarzen Partikel nach oben. Und eine positive Ladung bringt die weißen Partikel nach vorne.

Dreifarbiges 2,9″ E-Paper-Display-Modul

Wenn du ein E-Paper mit einem Mikrocontroller steuern möchtest, benötigst du einen Treiber, der die elektrischen Felder des Displays kontrolliert. Du kannst das E-Paper und den Treiber separat kaufen oder als Modul, das beides in einer Einheit integriert.

Das Display-Modul, das wir in diesem Tutorial verwenden, ist ein dreifarbiges (weiß, schwarz, rot) Display mit einer Größe von 2,9 Zoll, einer Auflösung von 296×128 Pixeln und einem eingebetteten Controller mit einer SPI Schnittstelle zur Kommunikation. Das Bild unten zeigt Vorder- und Rückseite des Display-Moduls:

Vorder- und Rückseite des E-Paper-Display-Moduls

Beachte, dass das Modul auf der Rückseite einen kleinen Jumper-Pad/Schalter hat, um von 4-Draht-SPI auf 3-Draht-SPI umzuschalten. Wir verwenden hier den Standard 4-Draht-SPI, daher musst du nichts ändern.

Back of e-Paper module with SPI-interface and controller — Rückseite des E-Paper-Moduls mit SPI-Schnittstelle und Controller

Das Display-Modul läuft mit 3,3V oder 5V, hat einen Standby-Verbrauch von 0,017mW und verbraucht beim Aktualisieren nur etwa 26,4mW. Die Zeit für eine vollständige Aktualisierung beträgt 15 Sekunden, eine partielle Aktualisierung wird nicht unterstützt. Wenn du mehr über die Unterschiede zwischen voller und partieller Aktualisierung erfahren möchtest, schau dir unser Partial Refresh of e-Paper Display Tutorial an.

Pinbelegung des E-Paper-Displays

Das Display-Modul verfügt über einen 8-poligen Anschluss für SPI Kommunikation und Stromversorgung mit folgenden Pins:

Pinout of e-Paper Display — Pinbelegung des E-Paper-Displays

BUSY zeigt an, dass das Display gerade Inhalte aktualisiert. RST steht für Reset. DC ist der Data Command-Pin, CS der Chip Select und CLK der Clock-Pin. DIN ist der Data Input-Pin. VCC und GND sind für die Stromversorgung. Das Display hat einen integrierten Spannungsregler und kann mit 3,3V oder 5V betrieben werden.

Installation der GxEPD2-Bibliothek für E-Paper

Bevor wir auf dem E-Paper zeichnen oder schreiben können, müssen wir install two libraries. Die Adafruit_GFX Bibliothek ist eine Kern-Grafikbibliothek, die eine gemeinsame Menge an Grafikprimitive (Text, Punkte, Linien, Kreise usw.) bereitstellt. Und die GxEPD2 Bibliothek liefert die Grafiktreiber-Software, um ein E-Paper über SPI zu steuern.

Öffne den Library Manger, suche nach „Adafruit_GFX“ und „GxEPD2“ und klicke auf „INSTALL“. Nach der Installation sollten die Bibliotheken im Library Manager wie folgt erscheinen.

Adafruit_GFX and GxEPD2 libraries in Library Manager — Adafruit_GFX und GxEPD2 Bibliotheken im Library Manager

In den folgenden zwei Abschnitten zeige ich dir, wie du das E-Paper-Display an einen ESP32 oder Arduino anschließt. Der ESP32 ist vorzuziehen, da er viel mehr Speicher hat, was den Code vereinfacht.

Anschluss des E-Paper-Displays an ESP32

Das Bild unten zeigt, wie man einen ESP32 lite mit dem E-Paper-Display verbindet. Während die meisten Pins konfigurierbar sind, musst du die Standard-SPI-Pins für dein ESP32-Board kennen, speziell für DIN und CLK. Beim ESP32 lite sind DIN Pin 23 und CLK Pin 18.

Connecting e-Paper to ESP32 via SPI — Anschluss des E-Paper an ESP32 via SPI

Wenn du Hilfe bei der Suche nach den Standard-SPI-Pins brauchst, schau dir das Find I2C and SPI default pins Tutorial an.

Die folgende Tabelle zeigt alle Verbindungen, die du herstellen musst. Beachte, dass du das Display-Modul mit 3,3V oder 5V versorgen kannst, aber der ESP32 lite hat nur einen 3,3V-Ausgang.

E-Paper-Display	ESP32 lite
CS/SS	5
SCL/SCK	18
SDA/DIN/MOSI	23
BUSY	15
RES/RST	2
DC	0
VCC	3,3V
GND	G

Du kannst ein Breadboard verwenden, um alles zu verdrahten. Ich habe das Display allerdings direkt mit Dupont-Kabeln an den ESP32 angeschlossen. Das Bild unten zeigt, wie mein Aufbau aussah.

Wiring of E-Paper with ESP32 lite — Verdrahtung des E-Paper mit ESP32 lite

Testcode für E-Paper mit ESP32

Als Nächstes schreiben wir einfachen Code, um die Funktion des Displays zu testen. Wir zeigen den Text „Makerguides“, wobei „Maker“ in Schwarz und „guides“ in Rot dargestellt wird.

#include "GxEPD2_3C.h"

#define EPD_CS 5  
#define EPD_DC 0  
#define EPD_RST 2  
#define EPD_BUSY 15  
// SCL/SCK/CLK  = 18,
// SDA/DIN/MOSI = 23

GxEPD2_3C<GxEPD2_290_C90c, GxEPD2_290_C90c::HEIGHT> 
  epd(GxEPD2_290_C90c(EPD_CS , EPD_DC, EPD_RST, EPD_BUSY));

void setup() {
  epd.init(115200);
  epd.setRotation(1);
  
  epd.setTextSize(2);
  epd.setFullWindow();
  epd.fillScreen(GxEPD_WHITE);     

  epd.setCursor(80, 60);
  epd.setTextColor(GxEPD_BLACK);
  epd.print("Maker"); 

  epd.setCursor(140, 60);
  epd.setTextColor(GxEPD_RED);
  epd.print("guides");   

  epd.display();
  epd.hibernate();
}

void loop() {}

Lass uns den Code in seine Teile zerlegen, um ihn besser zu verstehen.

Bibliothek einbinden

Wir beginnen mit dem Einbinden der notwendigen Bibliothek zur Steuerung des E-Paper-Displays. Die Bibliothek GxEPD2_3C.h stellt die Funktionen bereit, um mit dem dreifarbigen Display zu interagieren.

#include "GxEPD2_3C.h"

Wenn du ein 4-Farben-Display hast, würdest du stattdessen GxEPD2_4C.h oder GxEPD2_7C.h für ein 7-Farben-Display einbinden. Bei einem Schwarz-Weiß (SW) E-Paper verwendest du GxEPD2_BW.h

Pin-Definitionen

Als Nächstes definieren wir die Pins, die für die Verbindung des Displays mit dem ESP32 über die SPI-Schnittstelle verwendet werden:

#define EPD_CS 5  
#define EPD_DC 0  
#define EPD_RST 2  
#define EPD_BUSY 15

Display-Objekt erstellen

Wir erstellen eine Instanz des E-Paper-Display-Objekts mit den definierten Pins. Die Template-Parameter geben auch den Displaytyp und die Höhe an.

GxEPD2_3C<GxEPD2_290_C90c, GxEPD2_290_C90c::HEIGHT>
  epd(GxEPD2_290_C90c(EPD_CS , EPD_DC, EPD_RST, EPD_BUSY));

Das ist die wichtigste Zeile im Code. Wenn dein Display nichts oder fehlerhafte Texte/Bilder anzeigt, ist entweder die Verkabelung falsch oder der falsche Display-Treiber gewählt.

Die Readme for GxEPD2 Bibliothek listet alle unterstützten Displays auf, die Details findest du in den Header-Dateien, z.B. GxEPD2.h. Finde den Display-Treiber, der zu deinem Display passt. Das erfordert manchmal etwas Ausprobieren.

Setup-Funktion

In der setup() Funktion initialisieren wir die Kommunikation mit dem Display mit einer Baudrate von 115200. Wir setzen außerdem die Rotation des Displays auf 1 (90 Grad), also Querformat.

epd.init(115200);
epd.setRotation(1);

Danach konfigurieren wir die Textgröße und bereiten das Display zum Zeichnen vor.

epd.setTextSize(2);
epd.setFullWindow();
epd.fillScreen(GxEPD_WHITE);

Wir setzen den Cursor und die Textfarbe auf Schwarz, bevor wir „Maker“ auf das Display schreiben.

epd.setCursor(80, 60);
epd.setTextColor(GxEPD_BLACK);
epd.print("Maker");

Anschließend ändern wir die Cursorposition und Textfarbe auf Rot, um „guides“ zu schreiben.

epd.setCursor(140, 60);
epd.setTextColor(GxEPD_RED);
epd.print("guides");

Beide Druckbefehle zusammen ergeben den Text „Makerguides“ in der Mitte des Displays. Die Ausgabe auf deinem Display sollte wie folgt aussehen:

Output on e-Paper display — Ausgabe auf dem E-Paper-Display

Zum Schluss rufen wir epd.display() auf, um den Text auf dem Bildschirm darzustellen und versetzen das Display in den Ruhezustand, um Strom zu sparen.

epd.display();
epd.hibernate();

Loop-Funktion

Die loop() Funktion ist in diesem Beispiel leer, da wir den Text nur einmal initialisieren und anzeigen müssen. Das Display bleibt im Energiesparmodus und zeigt den Text weiter an, selbst wenn die Stromversorgung komplett getrennt wird.

void loop() {}

Wenn du den Code hochlädst und ausführst, wirst du sehen, wie das Display etwa 15 Sekunden lang flackert, während der Text langsam erscheint (siehe das kurze Video unten).

Vollständige Aktualisierung des E-Paper-Displays

Das nennt man eine „Vollständige Aktualisierung„, bei der der gesamte Bildschirm gelöscht und alle Pixel neu gezeichnet werden. Dieser Vorgang beseitigt Geisterbilder oder Überreste vorheriger Inhalte.

Eine „Partielle Aktualisierung“ hingegen aktualisiert nur bestimmte Bereiche des Bildschirms. Diese Methode ist viel schneller (< 0,3 Sekunden) und vermeidet das Flackern. Beispiele findest du im Partial Refresh of e-Paper Display Tutorial.

Während partielle Aktualisierungen bei monochromen E-Paper-Displays üblich sind, unterstützen viele dreifarbige Displays, einschließlich des hier verwendeten, diese nicht. Das schränkt ihre Anwendung auf Fälle ein, in denen Inhalte selten aktualisiert werden, z.B. einmal pro Stunde. Andernfalls ist das Flackern und die langsame Aktualisierung zu störend.

Anschluss des E-Paper-Displays an Arduino

In diesem Abschnitt verbinden wir das E-Paper-Display mit einem Arduino Uno statt einem ESP32. Die Anzahl der Verbindungen ist gleich, nur die Pins sind anders. Wie bereits erwähnt, sind die meisten Pins konfigurierbar, aber für DIN und CLK müssen SPI-spezifische Pins verwendet werden. Beim Arduino Uno ist DIN Pin 11 und CLK Pin 13.

Connecting E-Paper to Arduino Uno via SPI — Anschluss des E-Paper an Arduino Uno via SPI

Die folgende Tabelle listet alle weiteren Verbindungen auf. Für die Stromversorgung kannst du 5V statt 3,3V verwenden.

E-Paper-Display	Arduino UNO
CS/SS	4
SCL/SCK/CLK	13
SDA/DIN/MOSI	11
BUSY	7
RES/RST	6
DC	5
VCC	3,3V
GND	G

Testcode für E-Paper mit Arduino Uno

Der Testcode für das E-Paper mit Arduino Uno ist ähnlich wie der für den ESP32, mit zwei wichtigen Unterschieden, die durch den kleinen Speicher des Arduino Uno bedingt sind.

Schau dir den Code zuerst kurz an und lies vielleicht den ESP32-Beispielcode zum besseren Verständnis. Danach besprechen wir die Unterschiede.

#include "GxEPD2_3C.h"

#define EPD_CS 4
#define EPD_DC 5
#define EPD_RST 6
#define EPD_BUSY 7
// SCL/SCK/CLK  = 13,
// SDA/DIN/MOSI = 11

#define MAX_BUFF 1024
#define MAX_HEIGHT(EPD) ((MAX_BUFF / 2) / (EPD::WIDTH / 8))

GxEPD2_3C<GxEPD2_290_C90c, MAX_HEIGHT(GxEPD2_290_C90c)>
   epd(GxEPD2_290_C90c(EPD_CS, EPD_DC, EPD_RST, EPD_BUSY));

void setup() {
  epd.init(115200);
  epd.setRotation(1);
  epd.setTextSize(2);
  epd.setFullWindow();

  epd.firstPage();
  do {
    epd.fillScreen(GxEPD_WHITE);

    epd.setCursor(80, 60);
    epd.setTextColor(GxEPD_BLACK);
    epd.print("Maker");

    epd.setCursor(140, 60);
    epd.setTextColor(GxEPD_RED);
    epd.print("guides");

  } while (epd.nextPage());
  epd.hibernate();
}

void loop() {}

Wie zuvor schreibt der Code den Text „Makerguides“ in Schwarz und Rot auf das Display. Allerdings ist die Art, wie das Display-Objekt erstellt wird, anders. Insbesondere müssen wir die Höhe (MAX_HEIGHT) des Displays definieren:

#define MAX_BUFF 1024
#define MAX_HEIGHT(EPD) ((MAX_BUFF / 2) / (EPD::WIDTH / 8))

GxEPD2_3C<GxEPD2_290_C90c, MAX_HEIGHT(GxEPD2_290_C90c)>
   epd(GxEPD2_290_C90c(EPD_CS, EPD_DC, EPD_RST, EPD_BUSY));

Das E-Paper-Display hat eine Auflösung von 296 * 128 Pixeln, also müssen insgesamt 37888 Pixel gesetzt werden, um den Inhalt zu aktualisieren. Normalerweise wird der Inhalt zuerst in einem Display-Puffer gespeichert und dann an das Display gesendet. Ein Arduino Uno hat jedoch nur 2KB SRAM = 2048 Bytes, was zu klein ist, um den kompletten Puffer zu halten. Deshalb definieren wir einen kleineren Display-Puffer MAX_BUFF = 1024.

Mit dem kleineren Puffer können wir nicht den kompletten Inhalt senden, sondern nur einen Streifen von MAX_HEIGHT, der sich aus MAX_BUFF und der Breite (EPD::WIDTH) des Displays berechnet. Die Höhe des Displays wird über MAX_HEIGHT(GxEPD2_290_C90c) ermittelt.

Paged Drawing

Das Display wird dann im paged drawing Modus aktualisiert. Dabei wird das Display in kleinere Abschnitte oder Streifen, sogenannte „Pages“, unterteilt. Statt den gesamten Inhalt zu laden, verarbeitet der Arduino jeweils nur eine Page.

Das siehst du in der do–while Schleife in der setup Funktion, wo die Pages wiederholt gezeichnet werden, bis der gesamte Displayinhalt aktualisiert ist.

  epd.firstPage();
  do {
     ...
  } while (epd.nextPage());

Beim Aktualisieren zeichnet der Arduino den Inhalt der aktuellen Page in den Speicher und sendet diese dann an das E-Paper-Display. Nach der Aktualisierung kann der Arduino den Puffer leeren und die nächste Page laden.

Beachte, dass der Display-Puffer und der Code des Sketches denselben Speicher teilen. Wenn dein Code größer wird, musst du MAX_BUFF reduzieren, um beides in den SRAM zu bekommen. Wenn du beim Kompilieren folgende Fehlermeldung erhältst, ist MAX_BUFF zu hoch eingestellt:

Not enough memory; see https://support.arduino.cc/hc/en-us/articles/360013825179 for tips on reducing your footprint. 
data section exceeds available space in board.
Compilation error: data section exceeds available space in board

Die explizite do–while Schleife für paged drawing ist ziemlich umständlich und unübersichtlich. Glücklicherweise bietet die GxEPD2 Bibliothek eine Alternative. Du kannst eine Zeichenfunktion definieren und dann epd.drawPaged(...) für paged drawing aufrufen. Das folgende Codebeispiel zeigt, wie das für den obigen Testcode aussieht:

...

void draw(const void* pv) {
  epd.fillScreen(GxEPD_WHITE);

  epd.setCursor(80, 60);
  epd.setTextColor(GxEPD_BLACK);
  epd.print("Maker");

  epd.setCursor(140, 60);
  epd.setTextColor(GxEPD_RED);
  epd.print("guides");
}

void setup() {
  ...
  epd.drawPaged(draw, 0);
  epd.hibernate();
}

void loop() {}

Die Zeichenfunktion draw() nimmt einen Zeiger pv entgegen, mit dem du Parameter übergeben kannst, was wir hier aber nicht nutzen. Beim Aufruf von epd.drawPaged(draw, 0) übergeben wir einfach 0 als Parameterzeiger.

Die Verwendung von Zeichenfunktionen für paged redraws macht den Code lesbarer und erweiterbar. Du kannst mehrere Zeichenfunktionen haben, was besonders bei partiellen und vollständigen Aktualisierungen nützlich ist. Siehe das Digital Clock on e-Paper Display Tutorial für ein Beispiel.

Beachte, dass du paged drawing auch verwenden kannst, wenn dein Mikrocontroller groß genug ist, um den kompletten Display-Puffer zu halten. Zum Beispiel würde der Testcode für den Arduino Uno ohne Änderungen (außer der Verkabelung) auf einem ESP32 laufen. Generell wird paged drawing empfohlen.

Empfehlungen

Die Waveshare Manual gibt folgende Empfehlungen für den Betrieb eines E-Paper-Displays (gekürzt und von mir umformuliert):

Vollständige Aktualisierung: Das E-Paper-Display flackert während des Aktualisierungsvorgangs mehrmals (die Anzahl der Flacker hängt von der Aktualisierungszeit ab). Das Flackern dient dazu, Nachbilder zu entfernen und den besten Anzeigeeffekt zu erzielen.

Partielle Aktualisierung: Hier flackert das Display während der Aktualisierung nicht. Nach mehreren partiellen Aktualisierungen sollte eine vollständige Aktualisierung durchgeführt werden, um Restbilder zu entfernen. Andernfalls können diese dauerhaft werden.

Es wird empfohlen, das Aktualisierungsintervall des E-Ink-Bildschirms auf mindestens 180 Sekunden zu setzen (außer bei Produkten, die partielle Aktualisierung unterstützen).

Nach einer Aktualisierung sollte das Display ausgeschaltet oder in den Ruhezustand versetzt werden. Das verlängert die Lebensdauer des Displays und reduziert den Stromverbrauch.

Bei dreifarbigen E-Ink-Bildschirmen wird empfohlen, das Display mindestens einmal alle 24 Stunden zu aktualisieren.

E-Paper-Displays sind für den Innenbereich empfohlen, nicht für den Außenbereich. Wenn du das Display draußen verwenden möchtest, platziere es im Schatten und decke den weißen Klebeteil des Verbindungskabels des E-Paper-Bildschirms vollständig mit 3M-Klebeband ab.

Fazit

E-Paper-Displays bieten viele Vorteile, die sie für verschiedene Projekte attraktiv machen. Sie verbrauchen sehr wenig Strom, besonders bei statischen Bildern, was ideal für batteriebetriebene Geräte ist. Ihre hervorragende Lesbarkeit bei hellem Sonnenlicht macht sie für den Außeneinsatz geeignet, während die weiten Betrachtungswinkel für Klarheit aus verschiedenen Perspektiven sorgen. Außerdem sind E-Paper dünn und leicht, was die Integration in verschiedene Designs erleichtert.

Allerdings haben E-Paper-Displays eine langsame Aktualisierungsrate im Vergleich zu LCDs oder OLEDs, was ihre Nutzung in Projekten mit dynamischen Inhalten einschränkt. Die Farboptionen sind ebenfalls begrenzt; Schwarz-Weiß-Displays zeigen nur zwei Farben, während dreifarbige Displays auf drei Farben beschränkt sind, was die Designflexibilität beeinflussen kann. Zudem sind E-Paper-Displays oft teurer als andere Displaytypen, besonders bei größeren Größen.

Monochrome E-Paper-Displays haben viel schnellere Aktualisierungszeiten (< 3 Sekunden) als dreifarbige Displays und unterstützen typischerweise partielle Aktualisierungen für noch schnellere, flimmerfreie Updates. Sie sind schnell genug für Uhrenanzeigen, zum Beispiel. Siehe unsere Tutorials Digital Clock on e-Paper Display und Analog Clock on e-Paper Display.

Die sehr langsame Aktualisierungszeit (15 Sekunden) von dreifarbigen Displays begrenzt deren Einsatzmöglichkeiten. Der häufigste Anwendungsfall sind elektronische Preisschilder. Aber du kannst sie auch für andere Anwendungen mit langsamen Aktualisierungszyklen verwenden, z.B. Wetterdaten, die nur alle 15 Minuten aktualisiert werden müssen.

Unser Weather Station on e-Paper Display Tutorial verwendet ein monochromes E-Paper, aber ein dreifarbiges E-Paper wäre auch eine Option. Und wenn du noch mehr Farben brauchst, schau dir das 4-color E-paper display with ESP32 Tutorial an.

Wenn du Fragen hast, kannst du sie gerne im Kommentarbereich stellen.

Viel Spaß beim Tüfteln ; )

Puneeth Kumar