MaxBotix MB1240 Ultraschall-Entfernungssensor Arduino Tutorial

Der MB1240 XL-MaxSonar-EZ4 ist ein leistungsstarker Ultraschall-Entfernungssensor mit einer Reichweite von 20 bis 765 cm. Er ist eine großartige Alternative zum beliebten HC-SR04, wenn du eine bessere Rauschfilterung und Zuverlässigkeit benötigst. Obwohl dieses Tutorial für den MB1240 geschrieben wurde, kann es auch für andere MaxBotix-Sensoren verwendet werden.

In diesem Tutorial lernst du, wie der Sensor funktioniert und wie du ihn mit einem Arduino verwenden kannst. Ich habe 3 Beispiele mit Schaltplänen beigefügt, die den Grundbetrieb des Sensors zeigen. Wir betrachten die verschiedenen Ausgänge des Sensors und wie du den Sensor mit einem Taster auslösen kannst.

Materialien

Hardware-Komponenten

MB1240 XL-MaxSonar EZ4	× 1	Amazon
Arduino Uno Rev3	× 1	Amazon
Breadboard	× 1	Amazon
Jumper wires	~ 10	Amazon
Header pins (optional)	× 7	Amazon
Momentary push button	× 1	Amazon
USB cable type A/B	× 1	Amazon

Software

Arduino IDE

Makerguides is a participant in affiliate advertising programs designed to provide a means for sites to earn advertising fees by linking to Amazon, AliExpress, Elecrow, and other sites. As an Affiliate we may earn from qualifying purchases.

Wie funktioniert ein Ultraschallsensor?

Ein Ultraschall-Entfernungssensor arbeitet, indem er Ultraschallwellen aussendet. Diese Ultraschallwellen werden von einem Objekt reflektiert und der Sensor erkennt sie. Durch Messen der Zeit, die zwischen Aussenden und Empfangen der Schallwellen vergeht, kannst du die Entfernung zwischen Sensor und Objekt berechnen.

Entfernung (cm) = Schallgeschwindigkeit (cm/µs) × Zeit (µs) / 2

Dabei ist Zeit die Zeit zwischen Aussenden und Empfangen der Schallwellen in Mikrosekunden.

How Ultrasonic Sensors Work Maxbotix — Funktionsprinzip von Ultraschall-Entfernungssensoren. Quelle: https://www.maxbotix.com/

Beachte, dass du das Ergebnis durch zwei teilen musst. Das liegt daran, dass die Schallwellen vom Sensor zum Objekt und zurück vom Objekt zum Sensor reisen. Die Entfernung zwischen Sensor und Objekt ist also nur die Hälfte der zurückgelegten Strecke der Schallwellen.

Für weitere Informationen, wie Ultraschallsensoren funktionieren, kannst du meinen Artikel How to use an HC-SR04 Ultrasonic Distance Sensor with Arduino lesen. In diesem Artikel werden die Funktionsprinzipien eines Ultraschall-Entfernungssensors ausführlicher erklärt.

Informationen zum Sensor

Der MB1240 XL-MaxSonar-EZ4 ist ein Ultraschall-Entfernungssensor von MaxBotix Inc. MaxBotix ist ein US-amerikanischer Hersteller, der sich auf Ultraschallsensoren spezialisiert hat. Sie fertigen Sensoren für alle Arten von Anwendungen, sowohl für den Innen- als auch den Außenbereich.

Der MB1240 ist einer ihrer beliebtesten Sensoren und ideal für Robotikanwendungen. Die XL-MaxSonar-EZ-Familie hat eine hohe Toleranz gegenüber Störungen durch akustisches oder elektrisches Rauschen. Das bedeutet, du kannst ihn in Robotikanwendungen mit mehreren Motoren und Servos verwenden.

Der MB1240, den ich in diesem Tutorial verwendet habe, hat eine Reichweite von bis zu 765 cm und bietet eine Auflösung von 1 cm. MaxBotix verkauft auch Sensoren mit einer Auflösung von 1 mm (HRLV-MaxSonar-EZ) und höherer Abtastrate (LV-MaxSonar-EZ). Die HR-Serie der Sensoren verfügt zudem über eine interne Temperaturkompensation.

TM1240 XL-MaxSonar-EZ4 Spezifikationen

Betriebsspannung	3,3 – 5,5 V
Betriebsstrom	3,4 mA durchschnittlich (100 mA Spitze)
Reichweite	(0)* 20 – 765 cm
Auflösung	1 cm
Frequenz	42 kHz
Abtastrate	10 Hz
Sensorausgänge	Analogspannung, Pulsbreite, RS232
Gesamtmaße	22,1 x 19,9 x 25,11 mm
Betriebstemperatur	0 – 65 °C
Vorteile	Klein, leicht, schmaler Strahl, automatische Kalibrierung (Spannung, Luftfeuchtigkeit, Umgebungsgeräusche), Firmware-Filterung, einfach zu bedienen
Hergestellt in	USA
Kosten	Check price

*Der Sensor hat praktisch keine Totzone, Objekte näher als 20 cm werden als 20 cm gemessen.

Weitere Informationen findest du im Datenblatt hier:

MB1240 Datasheet

MaxBotix Sensorausgänge

Wie du in der obigen Spezifikationstabelle gesehen hast, haben die MaxBotix-Sensoren der MaxSonar-Familie verschiedene Ausgänge: Analogspannung, Pulsbreite und RS232 seriell sowie I2C. In diesem Tutorial betrachten wir sowohl den Analogspannungs- als auch den Pulsbreitenausgang.

Analogspannung

Dies ist wahrscheinlich die einfachste Methode, die gemessene Entfernung vom Sensor auszulesen. Der Analogspannungsausgang des Sensors liefert eine lineare Spannung, die größer wird, je weiter ein Zielobjekt vom Sensor entfernt ist.

136_AnalogVoltage_lg — Analogspannungsausgang (source)

Wir können diesen Ausgang mit einem Mikrocontroller wie dem Arduino auslesen und die Entfernung berechnen, indem wir den Messwert mit einem konstanten Skalierungsfaktor multiplizieren (dieser Faktor hängt vom genauen Sensortyp ab, siehe Datenblatt).

Pulsbreite

Eine weitere Möglichkeit ist die Verwendung des Pulsbreitenausgangs. Dieser Pin gibt eine Pulsbreiten-Darstellung der Entfernung aus. Du kannst die pulseIn() Funktion im Arduino-Code verwenden, um die Länge dieses Ausgangspulses in Mikrosekunden (µs) zu messen. Um die Entfernung zu erhalten, musst du diesen Wert mit einem konstanten Skalierungsfaktor multiplizieren. Für den MB1240 (XL-MaxSonar-Sensoren) beträgt der Skalierungsfaktor 58 µs/cm. Du kannst also einfach die TOF-Messung durch 58 teilen, um die Entfernung in Zentimetern zu erhalten.

PW-Output — Pulsbreitenausgang. Quelle: https://www.maxbotix.com/

Für andere Sensortypen findest du die Skalierungsfaktoren in den Datenblättern.

MaxBotix MB1240 vs HC-SR04

Wenn du nach einem Ultraschall-Entfernungssensor suchst, bist du wahrscheinlich auch auf den beliebten HC-SR04 gestoßen. Dieser kostengünstige Sensor ist von vielen verschiedenen chinesischen Herstellern erhältlich. Der HC-SR04 und der MB1240 arbeiten nach einem ähnlichen Prinzip, aber es gibt einige wichtige Unterschiede (vor allem bei Qualität und Preis).

Das erste, was dir auffallen könnte, ist der Größenunterschied. Der MaxBotix MB1240 verwendet nur einen Ultraschallwandler zum Senden und Empfangen der Schallwellen. Der HC-SR04 hingegen verwendet zwei. Das bedeutet, dass der MB1240 deutlich kleiner ist.

Die Montage eines HC-SR04-Sensors kann schwierig sein und erfordert oft winzige Schrauben, während der MB1240 zwei Löcher für M3-Schrauben hat.

Für mich sind die Hauptvorteile der MaxBotix-Sensoren die automatische Echtzeitkalibrierung, der kleine Strahlwinkel, die hohe Störfestigkeit und die Onboard-Filterung.

Der MB1240 hat über seinen gesamten Messbereich (für große Objekte) einen wirklich schmalen Strahl. Das macht ihn ideal für die genaue Raumvermessung (z. B. bei Hindernisvermeidungsrobotern) und verhindert frühe Reflexionen von Objekten nahe am Sensor. Der HC-SR04 hat einen Strahl in Form eines 15°-3D-Kegels. Das bedeutet, dass du Objekte, die weit vom Sensor entfernt sind, nicht genau messen kannst. Der Strahl ist einfach zu breit und erfasst auch Objekte, die näher am Sensor sind.

Außerdem gefällt mir der Dauerbetrieb der Sensoren (dazu später mehr) und der analoge Ausgang. Der analoge Ausgang macht die Programmierung der Sensoren super einfach. Diese zusätzlichen Features sind sehr praktisch, aber beachte, dass der Preis auch deutlich höher ist als bei den chinesischen Sensoren. Insgesamt sind die MaxBotix-Sensoren eine gute Wahl, wenn du einen hochwertigen und zuverlässigen Sensor suchst. Zum Vergleich siehe die Tabelle unten.

MB1240 vs HC-SR04 Vergleichstabelle

	MB1240	HC-SR04
Betriebsspannung	3,3 – 5,5 V	5 V
Betriebsstrom	3,4 mA durchschnittlich (100 mA Spitze)	15 mA
Reichweite	(0) 20 – 765 cm	2 – 400 cm
Auflösung	1 cm	>3 mm
Strahlmuster	see here	15° Kegel
Frequenz	42 kHz	40 kHz
Sensorausgänge	Analogspannung, Pulsbreite, RS232	Pulsbreite
Abmessungen	22,1 x 19,9 x 25,11 mm	45 x 20 x 15 mm
Temperaturkompensation*	Nein	Nein
Filterung	Ja	Nein
Echtzeit-Autokalibrierung	Ja	Nein
Störfestigkeit	Hoch	Niedrig
Hergestellt in	USA	China
Preis	Check price	Check price

*Was du vielleicht nicht weißt: Die Schallgeschwindigkeit hängt stark von der Temperatur und Luftfeuchtigkeit ab. Die Schallgeschwindigkeit in Luft steigt um etwa 0,6 Meter pro Sekunde pro Grad Celsius.

Weder der HC-SR04 noch der MB1240 kompensieren während des Betriebs Änderungen der Lufttemperatur. Die XL-MaxSonar- und LV-MaxSonar-Sensoren gehen von einer Lufttemperatur von 22,5 Grad Celsius aus. Die HR line Sensorlinie verfügt über eine interne Temperaturkalibrierung, sodass du keine zusätzlichen Sensoren hinzufügen musst. Wenn du ein Beispiel sehen möchtest, das einen Temperatursensor zur Echtzeitkalibrierung der Schallgeschwindigkeit verwendet, schau dir das How to use an HC-SR04 Ultrasonic Distance Sensor with Arduino Tutorial an.

Verdrahtung – Anschluss des MaxBotix MB1240 an Arduino UNO

Wie in der Einleitung erwähnt, können MaxBotix-Sensoren in verschiedenen Modi betrieben werden. Die folgenden Schaltpläne zeigen, wie du den MB1240-Sensor für den Betrieb mit Analogspannung oder Pulsbreite an den Arduino anschließt.

Du kannst die Drähte direkt an den Sensor löten, oder Header-Pins (so habe ich es gemacht) oder einen Stecker installieren.

MaxBotix-MB1240-ultrasonic-distance-sensor-with-Arduino-UNO-analog-voltage-wiring-diagram-schematic — Schaltplan für Analogspannung

Die Anschlüsse sind auch in der folgenden Tabelle aufgeführt:

MB1240 Anschlüsse – Analogspannung

MaxBotix MB1240 Sensor	Arduino
GND	GND
V+	5 V
Pin 3	A0

MaxBotix-MB1240-ultrasonic-distance-sensor-with-Arduino-UNO-pulse-width-wiring-diagram-schematic — Schaltplan für Pulsbreite

MB1240 Anschlüsse – Pulsbreite

MaxBotix MB1240 Sensor	Arduino
GND	GND
V+	5 V
Pin 2	Pin 2

MaxBotix MB1240 Arduino Beispielcode – Analogspannung

Mit dem folgenden Beispiel kannst du die gemessene Entfernung auslesen und im seriellen Monitor anzeigen. Wie du siehst, ist der Code sehr einfach, aber unten findest du eine Erklärung, wie er funktioniert.

Du kannst den Beispielcode mit der Arduino IDE hochladen.

/* Arduino example code for MaxBotix MB1240 XL-MaxSonar-EZ4 
   ultrasonic distance sensor: analog voltage output. 
   More info: www.www.makerguides.com */

#define sensorPin A0

int distance = 0;

void setup() {
  Serial.begin(9600);
}

void read_sensor() {
  distance = analogRead(sensorPin) * 1;
}

void print_data() {
  Serial.print("distance = ");
  Serial.print(distance);
  Serial.println(" cm");
}

void loop() {
  read_sensor();
  print_data();
  delay(1000);
}

Im Serial Monitor (Strg + Shift + M) solltest du die folgende Ausgabe sehen.

MB1240 Analog voltage serial monitor output — MB1240 Serial Monitor Ausgabe

Wie der Code funktioniert

Der erste Schritt ist, den Anschluss-Pin zu definieren. Die Anweisung #define wird verwendet, um einem konstanten Wert einen Namen zu geben. Beim Kompilieren ersetzt der Compiler alle Verweise auf diese Konstante durch den definierten Wert. Überall, wo du sensorPin nennst, wird es beim Kompilieren durch A0 ersetzt.

#define sensorPin A0

Als Nächstes erstellen wir eine Variable, um die gemessene Entfernung zu speichern.

int distance = 0;

Im Setup initialisieren wir die serielle Kommunikation mit einer Baudrate von 9600. Später zeigen wir die gemessene Entfernung im seriellen Monitor an, den du mit Strg + Shift + M oder Tools > Serial Monitor öffnen kannst. Achte darauf, dass die Baudrate auch im seriellen Monitor auf 9600 eingestellt ist.

void setup() {
  Serial.begin(9600);
}

Danach habe ich zwei Funktionen erstellt: read_sensor und print_data.

In der Funktion read_sensor lesen wir einfach den analogen Spannungsausgang des Sensors mit der Funktion analogRead(pin) aus. Die Arduino-Boards enthalten einen mehrkanaligen 10-Bit-Analog-Digital-Wandler. Das bedeutet, dass die Eingangsspannung zwischen 0 und der Betriebsspannung in Ganzzahlen zwischen 0 und 1023 umgewandelt wird. Beim Arduino Uno entspricht das 5 Volt / 1024 Einheiten oder 4,9 mV pro Einheit.

Der MB1240 verwendet einen Skalierungsfaktor von (Vcc/1024) pro cm oder 4,9 mV/cm bei einer 5 V Versorgungsspannung. Das macht die Umrechnung des analogRead-Werts in Zentimeter sehr einfach, du kannst das Ergebnis einfach mit 1 multiplizieren (analogRead(sensorPin) = Entfernung in Zentimetern).

void read_sensor() {
  distance = analogRead(sensorPin) * 1;
}

In der Funktion print_data geben wir die gemessene Entfernung im seriellen Monitor aus.

void print_data() {
  Serial.print("distance = ");
  Serial.print(distance);
  Serial.println(" cm");
}

In der loop rufen wir zuerst die Funktion read_sensor auf, um die Entfernung zu erhalten, und dann print_data, um sie im seriellen Monitor anzuzeigen. Ich habe eine Verzögerung von 1000 Millisekunden hinzugefügt, du kannst sie aber auf 100 reduzieren, wenn du möchtest. Die Abtastrate des MB1240 beträgt 10 Hz, also kannst du 10 Messungen pro Sekunde durchführen.

void loop() {
  read_sensor();
  print_data();
  delay(1000);
}

MaxBotix MB1240 Arduino Beispielcode – Pulsbreite

In diesem Beispiel verwenden wir den anderen Ausgang des Sensors: den Pulsbreitenausgang.

/* Arduino example code for MaxBotix MB1240 XL-MaxSonar-EZ4 
   ultrasonic distance sensor: pulse width output.
   More info: www.www.makerguides.com */

#define sensorPin 2

long distance = 0;
long duration = 0;

void setup() {
  pinMode(sensorPin, INPUT);
  Serial.begin(9600);
}

void read_sensor() {
  duration = pulseIn(sensorPin, HIGH);
  distance = duration / 58;
}

void print_data() {
  Serial.print("distance = ");
  Serial.print(distance);
  Serial.println(" cm");
}

void loop() {
  read_sensor();
  print_data();
  delay(1000);
}

Code-Erklärung

Nach der Definition des Anschluss-Pins habe ich zwei Variablen erstellt: duration und distance. Duration speichert die Länge des vom Sensor gesendeten Pulses. Die Variable distance wird verwendet, um die berechnete Entfernung zu speichern.

long distance = 0;
long duration = 0;

Im Setup müssen wir neben der Initialisierung der seriellen Kommunikation den sensorPin als INPUT setzen. Dafür verwenden wir die Funktion pinMode(pin, mode).

void setup() {
  pinMode(sensorPin, INPUT);
  Serial.begin(9600);
}

Die Funktion read_sensor unterscheidet sich vom vorherigen Beispiel. Jetzt messen wir nicht die analoge Spannung, sondern die Länge des vom Sensor gesendeten Pulses. Dafür verwenden wir die Funktion pulseIn(pin, value). Diese Funktion wartet darauf, dass der Pin von LOW auf HIGH wechselt, startet die Zeitmessung, wartet dann, bis der Pin wieder LOW wird, und stoppt die Zeitmessung. Sie gibt die Pulsdauer in Mikrosekunden zurück.

Danach können wir die Entfernung in Zentimetern berechnen, indem wir die Dauer durch 58 teilen. Für andere MaxBotix-Sensoren findest du diesen Skalierungsfaktor im Datenblatt.

void read_sensor() {
  duration = pulseIn(sensorPin, HIGH);
  distance = duration / 58;
}

Der Rest des Codes ist wie im vorherigen Beispiel.

Trigger-Modus Betrieb

Alle MaxSonar-Sensoren arbeiten standardmäßig im Free-Running-Modus. Das bedeutet, dass der Sensor kontinuierlich misst, bis die Stromversorgung unterbrochen wird. Er sendet alle 99 ms zwanzig 42-kHz-Wellen (10 Hz Abtastrate für MB1240, siehe Datenblatt für andere Sensoren).

Dies ist in der Regel die einfachste Art, den Sensor zu betreiben, da du ihn nicht selbst auslösen musst und einfach eine Analogspannungs- oder Pulsbreitenmessung durchführen kannst, um die Entfernung zu erhalten.

Für einige Anwendungen, z. B. wenn der Sensor mit Batterie betrieben wird, kann es besser sein, den Sensor mit einem Trigger zu betreiben. Das bedeutet, dass du dem Sensor sagen kannst, wann er einen Messzyklus starten soll – nur wenn du es anweist. So kannst du den höchsten Stromverbrauch des Sensors steuern, der beim Aussenden eines Sonarpulses auftritt.

Der Sensor zieht den meisten Strom, wenn er einen Sonarpuls aussendet.

Um den Sensor mit einem Trigger zu betreiben, verwenden wir eine zusätzliche Verbindung zwischen Pin 4 des Sensors und dem Arduino. Wenn du diesen Pin nicht anschließt, wie in den vorherigen Beispielen, arbeitet der Sensor mit der im Datenblatt angegebenen Abtastrate.

Um den Sensor bei Bedarf auszulösen, musst du Pin 4 auf logisch LOW ziehen. Wenn du eine Messung durchführen möchtest, musst du Pin 4 für mindestens 20 μs auf HIGH ziehen. Der Sensor startet dann einen Messzyklus.

Der folgende Schaltplan zeigt dir, welche Verbindungen du für dieses Beispiel herstellen musst.

MaxBotix-MB1240-ultrasonic-distance-sensor-with-Arduino-UNO-pulse-width-non-continuous-operation-wiring-diagram-schematic — MaxBotix MB1240 mit Taster und Arduino Schaltplan

In diesem Beispiel verwenden wir einen Taster, um den Sensor auszulösen. Verbinde ein Bein mit Masse und das diagonal gegenüberliegende Bein mit Arduino Pin 4. Die Anschlüsse sind auch in der Tabelle unten aufgeführt.

MB1240 Anschlüsse – Trigger-Modus

Pin	Arduino
GND	GND
V+	5 V
Pin 2	Pin 2
Pin 4	Pin 3
Taster Bein 1	Pin 4
Taster Bein 2	GND

MaxBotix MB1240 Arduino Beispielcode – Trigger mit Taster

Du kannst diesen Beispielsketch verwenden, um den Sensor mit einem Trigger zu steuern. In diesem Fall nimmt der Sensor eine Messung vor, wenn du den Taster drückst, und zeigt die Entfernung im Serial Monitor an. Du kannst auch einfach die Funktion read_sensor aufrufen, wenn du eine Messung machen möchtest.

/* Arduino example code for MaxBotix MB1240 XL-MaxSonar-EZ4 
   ultrasonic distance sensor with push button. 
   More info: www.www.makerguides.com */

#define readPin 2
#define triggerPin 3
#define buttonPin 4

long distance = 0;
long duration = 0;

int buttonState = HIGH;
int previous = HIGH;
long time = 0;
long debounce = 200;

void setup() {
  pinMode(readPin, INPUT);
  pinMode(buttonPin, INPUT_PULLUP);
  pinMode(triggerPin, OUTPUT);
  digitalWrite(triggerPin, LOW);
  Serial.begin(9600);
  delay(3000);
  Serial.println("Sensor is ready, waiting for button press!");
}

void read_sensor() {
  digitalWrite(triggerPin, HIGH);
  delayMicroseconds(20);
  digitalWrite(triggerPin, LOW);
  duration = pulseIn(readPin, HIGH);
  distance = duration / 58;
  delay(100);
}

void print_data() {
  Serial.print("distance = ");
  Serial.print(distance);
  Serial.println(" cm");
}

void loop() {
  buttonState = digitalRead(buttonPin);

  if (buttonState == LOW && previous == HIGH && millis() - time > debounce) {
    read_sensor();
    print_data();
    time = millis();
  }

  previous = buttonState;
}

Im Serial Monitor (Strg + Shift + M) solltest du die folgende Ausgabe sehen.

MB1240 trigger mode serial monitor output — Serial Monitor Ausgabe

Wie der Code funktioniert

Der erste Schritt ist, die Anschlüsse zu definieren. Wir verwenden den Pulsbreitenausgang des Sensors, um die Entfernung auszulesen.

#define readPin 2
#define triggerPin 3
#define buttonPin 4

Neben den Variablen duration und distance aus dem vorherigen Beispiel benötigen wir weitere Variablen, um den Zustand des Tasters zu speichern. Die Variablen time und debounce werden verwendet, um das Entprellen des Eingangs zu realisieren.

Du kannst die Entprellzeit erhöhen, wenn du Fehltrigger bekommst.

long distance = 0;
long duration = 0;

int buttonState = HIGH;
int previous = HIGH;
long time = 0;
long debounce = 200;

Im Setup setzen wir triggerPin als Ausgang und read sowie buttonPin als Eingang. Beachte, dass ich in der pinMode-Funktion INPUT_PULLUP verwendet habe. Im Atmega-Chip sind 20K Pullup-Widerstände integriert, die softwareseitig aktiviert werden können. Diese Einstellung zieht den buttonPin auf HIGH, wenn der Taster nicht gedrückt ist, und auf LOW, wenn du den Taster drückst.

Als Nächstes setzen wir triggerPin auf LOW, damit der Sensor nicht automatisch misst.

Um die Sensordaten auszugeben, starten wir die serielle Kommunikation mit 9600 Baud.

void setup() {
  pinMode(readPin, INPUT);
  pinMode(buttonPin, INPUT_PULLUP);
  pinMode(triggerPin, OUTPUT);
  digitalWrite(triggerPin, LOW);
  Serial.begin(9600);
  delay(3000);
  Serial.println("Sensor is ready, waiting for button press!");
}

Danach habe ich zwei Funktionen definiert: read_sensor und print_data.

In der Funktion read_sensor siehst du, dass wir triggerPin für 20 Mikrosekunden auf HIGH setzen. Das signalisiert dem Sensor, einen Sonarpuls auszusenden. Danach lesen wir die Länge des Ausgangspulses aus und wandeln sie in die Entfernung um (wie im vorherigen Beispiel). Ich habe eine Verzögerung von 100 ms hinzugefügt, da dies die minimale Zeit zwischen Messungen ist.

Die Funktion print_data ist wie in den vorherigen Beispielen.

void read_sensor() {
  digitalWrite(triggerPin, HIGH);
  delayMicroseconds(20);
  digitalWrite(triggerPin, LOW);
  duration = pulseIn(readPin, HIGH);
  distance = duration / 58;
  delay(100);
}

In der loop lesen wir zuerst den Zustand des Tasters (gedrückt / nicht gedrückt) und speichern ihn in buttonState. Die nächste Zeile prüft, ob du den Taster gedrückt hast (d. h. der Eingang ging von HIGH auf LOW) und ob seit dem letzten Drücken genug Zeit vergangen ist, um Störungen zu ignorieren.

Wenn das zutrifft, werden die Funktionen read_sensor und print_data aufgerufen und der Timer zurückgesetzt.

void loop() {
  buttonState = digitalRead(buttonPin);

  if (buttonState == LOW && previous == HIGH && millis() - time > debounce) {
    read_sensor();
    print_data();
    time = millis();
  }

  previous = buttonState;
}

Zum Schluss wird die Variable previous auf den aktuellen buttonState gesetzt.

XL-MaxSonar-EZ-Mechanical Dimensions — XL-MaxSonar Board

CAD

MaxBotix stellt auf seiner Website kostenlose CAD-Dateien für alle seine Sensoren zur Verfügung. Das macht das Entwerfen von individuellen Teilen oder Halterungen für den Sensor sehr einfach. Du kannst unten eine Zip-Datei mit einem 3D-Modell des Sensors herunterladen (7 verschiedene Dateiformate). Weitere Modelle verschiedener Sensoren findest du auf ihrer Website Website.

XL-MaxSonar-EZ.zip