Sistema de riego automático de plantas con Arduino IoT Cloud

En este proyecto, aprenderás a crear un sistema de riego automático de interior con Arduino IoT Cloud. Este sistema te permite monitorizar y regar tus plantas desde cualquier parte del mundo y es una gran introducción al internet de las cosas.

He incluido las instrucciones de construcción, una guía de inicio para el Arduino IoT Cloud y todo el código necesario. Este proyecto utiliza una placa Arduino MKR1000 IoT, un sensor capacitivo de humedad del suelo, un sensor de temperatura y humedad, una pantalla LCD I2C y una bomba de agua. También es posible realizar este proyecto con un Arduino normal (no conectado a internet).

Tenga en cuenta que esto es principalmente una prueba de concepto, es decir, construir este sistema para una sola planta es bastante caro y probablemente no tenga mucho sentido. Sin embargo, ahora que sé cómo funciona todo, puedo ampliar fácilmente el sistema y añadir más funciones en el futuro.

Si tiene alguna pregunta o sugerencia, deje un comentario a continuación.

Para obtener más información sobre algunos de los componentes utilizados en este proyecto, consulta los siguientes tutoriales:

• Cómo controlar un carácter I2C LCD con Arduino
• Cómo utilizar los sensores DHT11 y DHT22 con Arduino

Suministros

Componentes de hardware

	Arduino MKR1000	× 1	Amazon
	Arduino MKR Relay Proto Shield	× 1	Arduino
	Sensor capacitivo de humedad del suelo	× 1	Amazon
	Sensor de temperatura y humedad AM2301A (DHT21)	× 1	Amazon
	LCD I2C de 20×4 caracteres	× 1	Amazon
	Minibomba sumergible	× 1	Amazon
	Tubo de PVC 6 x 9 mm	1 m	Amazon
	Contenedor IKEA con tapa	× 1	IKEA
	Caja de proyectos 120 x 80 x 50 mm	× 1	Amazon

Ten en cuenta que también puedes utilizar cualquiera de las otras placas Arduino IoT con conectividad Wi-Fi, como la Arduino MKR WiFi 1010 o la más económica Arduino Nano 33 IoT. La ventaja de las placas MKR es que encajan en el Arduino MKR Relay Proto Shield, lo que facilita mucho el cableado.

Para el depósito de agua, puedes usar cualquier cosa que tengas por ahí (yo usé un recipiente de IKEA para almacenar alimentos de mi cocina).

Aplicaciones y servicios en línea

	Editor web de Arduino
	Arduino IoT Cloud

Makerguides.com is a participant in the Amazon Services LLC Associates Program, an affiliate advertising program designed to provide a means for sites to earn advertising fees by advertising and linking to products on Amazon.com. As an Amazon Associate we earn from qualifying purchases.

Montaje del sistema

Todos los componentes están conectados a una caja de proyecto central que se monta en la tapa del contenedor IKEA.

Para montar el Arduino MKR Relay Proto Shield, imprimí en 3D una sencilla placa adaptadora. Un pequeño orificio en el lateral de la caja del proyecto permite acceder al puerto micro USB del MKR1000 que se utiliza para alimentar el sistema y programar la placa.

Sensor de humedad del suelo

Para este proyecto, he utilizado un sensor de humedad del suelo capacitivo con una salida analógica. Los sensores capacitivos son más resistentes a la corrosión que los resistivos, pero no son 100% impermeables. Como están hechos de una placa de circuito impreso estándar con un sustrato compuesto, el agua puede entrar fácilmente por los lados de la placa. Los componentes electrónicos de la parte superior del sensor tampoco están protegidos del agua de ninguna manera.

Para hacer el sensor un poco más resistente al agua, recubrí los bordes y la electrónica con un poco de esmalte de uñas transparente. Un verdadero recubrimiento conformado es probablemente mejor, pero el esmalte de uñas funciona bastante bien como una alternativa barata.

El cable que venía con el sensor era bastante corto, así que hice uno nuevo. También puedes soldar cables más largos al cable original.

Conexión del sensor de humedad del suelo al Arduino MKR1000

La siguiente tabla le muestra las conexiones que debe realizar.

Sensor de humedad del suelo	Arduino MKR1000
GND	GND
VCC	3.3 V
AOUT	A2

Escudo de la bomba y del relé

Para regar las plantas, he utilizado una pequeña bomba sumergible que puede alimentarse con 3,3 V. La bomba se controla con el relé 1 del Arduino MKR Relay Proto Shield. Como la bomba sólo consume unos 200 mA, se puede alimentar directamente desde la salida de 3,3 V del MKR1000.

Si quieres usar una bomba más grande, tienes que usar una fuente de alimentación externa. Asegúrate de que la corriente nominal de la bomba está dentro de las especificaciones de los relés.

El cable negro de la bomba se conecta a tierra. El cable rojo va al lado NO (normalmente abierto) del relé. El COM se conecta a la salida de 3,3 V del MKR1000. Ten en cuenta que estos 3,3 V están disponibles en uno de los terminales de tornillo del Proto Shield.

Sensor de temperatura y humedad

Aunque no es estrictamente necesario para el riego automático de las plantas, pensé que un sensor de temperatura y humedad sería un buen complemento para el sistema. Para este proyecto, utilicé un sensor AM2301A que viene en una caja con los cables ya conectados. Este sensor está fabricado por ASAIR, que también fabrica los populares sensores DHT11 y DHT22.

Para obtener más información sobre los sensores de temperatura y humedad DHT, consulte el siguiente tutorial:

• Cómo utilizar los sensores DHT11 y DHT22 con Arduino

Conexión del sensor de temperatura y humedad AM2301A

La siguiente tabla le muestra las conexiones que debe realizar.

Sensor de temperatura y humedad AM2301A	Arduino MKR1000
Negro	GND
Rojo	3.3 V
Amarillo	A1

He montado el sensor en el lateral de la caja de proyecto. Tenga en cuenta que he perforado un pequeño agujero en la caja del proyecto y en la parte posterior del sensor para pasar los cables.

I2C LCD

Además de la Nube IoT de Arduino, los datos del sensor también se muestran en la pantalla LCD I2C de 20×4 montada en la tapa de la caja del proyecto.

Yo corté una abertura en la caja del proyecto utilizando mi fresadora CNC casera, pero también podrías utilizar una sierra de calar o incluso un cúter afilado.

La pantalla LCD se alimenta normalmente con 5 V, pero parece que funciona bien a 3,3 V. Gracias al módulo I2C montado en la parte posterior de la pantalla LCD, sólo necesita conectar dos cables, SDA y SCL, al MKR1000. Las conexiones están disponibles en los terminales de tornillo de la pantalla, así que el cableado de la pantalla es muy fácil.

Conexiones I2C LCD

LCD I2C de 20×4 caracteres	Arduino MKR1000
GND	GND
VCC	3.3 V
SDA	SDA
SCL	SCL

He escrito un tutorial detallado sobre el uso de LCDs I2C con Arduino que puedes encontrar aquí:

• Cómo controlar un carácter I2C LCD con Arduino

Nota sobre el cableado

Como habrás visto, todos los sensores, la pantalla LCD y la bomba deben estar conectados a 3,3 V y GND. El Arduino MKR Relay Proto Shield sólo tiene una salida de energía y meter todos los cables en un terminal de tornillo no es una buena idea. En su lugar, puedes usar algo como las tuercas de palanca de Wago como punto de distribución de energía.

La manguera de agua

En un principio, planeé simplemente pegar el extremo del tubo de PVC en algún lugar del centro de la jardinera. Sin embargo, descubrí que esto dejaba una parte de la jardinera empapada y el resto completamente seco.

Mi solución fue perforar un montón de pequeños agujeros (1 mm) con una separación de unos 2 cm en los últimos 30 - 40 cm del tubo. Imprimí en 3D un tapón para el extremo del tubo y unos soportes para clavarlos en el suelo.

Puedes descargar los archivos STL aquí si quieres imprimir los tuyos:

Esto parece funcionar bastante bien para que la tierra se humedezca uniformemente.

Cómo empezar con Arduino IoT Cloud

En la siguiente sección, explicaré cómo empezar con Arduino IoT Cloud.

El primer paso es ir a https://create.arduino.cc/. En esta página web encontrarás el Editor Web, una guía de iniciación, el Gestor de Dispositivos y un enlace a Arduino IoT Cloud.

Instalación del plugin Arduino Create

Hay varias maneras de instalar y configurar una nueva placa, pero creo que es más fácil hacerlo a través de la página de inicio. Haga clic en el icono de Introducción y desplácese hasta la parte inferior de la página donde dice Instalar Arduino Create Plugin. Este plugin te permite cargar bocetos desde el Editor Web de Arduino a tu placa o dispositivo.

Después de hacer clic en el icono de Arduino Create Plugin en la parte inferior de la página, haga clic en iniciar y descargar e instalar el plugin. El asistente de configuración comprobará si has instalado correctamente el plugin. Si lo has hecho, deberías ver la página de abajo.

Configuración de un tablero IoT

Ahora vuelve a la página de inicio haciendo clic en el icono de la parte superior de la página. El siguiente paso es configurar una nueva placa IoT. Para este proyecto, he utilizado la Arduino MKR1000. Si no estás seguro de cuál es el nombre de tu placa, puedes hacer clic en el icono Autodetectar placa Arduino.

Se abrirá el asistente de configuración de IoT que le guiará en la configuración y prueba de la placa.

Haga clic en el inicio y conecte la placa a su ordenador con un cable USB. Si has instalado correctamente el plugin Arduino Create, el ordenador debería ser capaz de detectar tu dispositivo.

A continuación, dale un nombre a tu placa. Yo simplemente llamé a la placa MKR1000_1. Asegúrate de usar un nombre que sea fácil de reconocer, especialmente si estás usando varias placas para diferentes proyectos.

Después de esto, el chip criptográfico del MKR1000 necesita ser configurado, lo que lleva hasta 5 minutos. Cada MKR1000 está equipado con un chip criptográfico Microchip ECC508. Este chip se utiliza para almacenar la identidad de tu placa de forma segura cuando está vinculada a tu cuenta de Arduino.

A continuación, puedes cargar un sketch de ejemplo que te permitirá probar la funcionalidad de la placa y encender y apagar el LED de la placa a través del monitor de red. En la pestaña Secreto del sketch, tienes que introducir el nombre y la contraseña de tu red wifi local.

En la página siguiente, haga clic en el carácter LED para encender y apagar el LED de la placa.

Si todo ha ido bien, deberías ver la página de abajo.

Creación de una nueva cosa

Después de configurar un nuevo dispositivo IoT, puedes volver al panel de control de Arduino Create y hacer clic en el icono de Arduino IoT Cloud.

Una vez que hagas clic en este icono, se abrirá la página "Tus Cosas" de Arduino IoT Cloud. En esta página, puedes crear nuevas Cosas, que es como Arduino llama a los dispositivos que puedes conectar a internet. En nuestro caso, la Cosa representa la placa Arduino MKR1000 con múltiples sensores conectados. Cada cosa puede tener múltiples propiedades como la temperatura, el estado de un LED, las coordenadas GPS, etc.

En la versión gratuita de la nube IoT, sólo puedes crear una Cosa con hasta cinco propiedades. Si quieres más de una, tienes que pasar al plan de pago de la nube Arduino. Dado que este proyecto sólo utiliza una cosa con menos de cinco propiedades, la versión gratuita funciona bien.

Haz clic en AÑADIR NUEVA COSA y dale un nombre. Yo llamé al mío Automatic_indoor_garden. Selecciona la placa MKR1000 que acabamos de configurar en el menú desplegable (MKR1000_1).

Ahora serás redirigido a una página donde puedes añadir propiedades a tu Cosa.

Añadir propiedades

Para este proyecto, he añadido tres propiedades diferentes: temperatura, humedad y contenido de humedad del suelo. Las propiedades representan variables en el código de Arduino y también son legibles en la Nube. Después de crear las propiedades y subir el código, podrás verlas en tu panel de control de Thing.

Añadir propiedades es muy fácil haciendo clic en AÑADIR PROPIEDAD. Tenga en cuenta que tiene que hacer este proceso tres veces.

Para cada propiedad es necesario establecer los siguientes parámetros:

• Nombre - el nombre que se mostrará en la lista de propiedades y en el widget.
• Nombre de la Variable - el nombre de la variable que utilizará en su Sketch para referirse a esta propiedad. No puede incluir caracteres especiales.
• Tipo - seleccione el tipo de propiedad correcto. Añadir el mínimo y el máximo para las medidas numéricas, para dibujar el widget, correctamente.
• Permiso
  • Lectura y escritura: la propiedad se puede establecer y mostrar en el panel de control de Arduino IoT Cloud.
  • Sólo lectura: la propiedad se enviará a Arduino IoT Cloud y estará disponible en su Dashboard.
• Actualización
  • Cuando el valor cambia: La propiedad se enviará a Arduino IoT Cloud cada vez que el cambio de valor sea mayor o igual al delta.
  • Regularmente: la propiedad se enviará a Arduino IoT Cloud cada vez que haya transcurrido el número de segundos especificado.
• Historial - Muestra una visualización de los datos históricos de la propiedad.

En la imagen de abajo, puedes ver los parámetros que he utilizado para la propiedad Temperatura. Tenga en cuenta que puede seleccionar uno de los muchos tipos de propiedades incorporadas como la Temperatura (Celsius) o puede crear uno personalizado.

Puede encontrar los parámetros de las demás propiedades en la siguiente tabla

Parámetros de la propiedad Thing

Nombre	Variable Nombre	Tipo	Permiso	Actualización
Temperatura	temperatura	Temperatura (Celsius) -20 °C - 60 °C	RO	Cada 10s
Humedad	humedad	Humedad relativa (porcentaje) 0 RH - 100 RH	RO	Cada 10s
Contenido de humedad del suelo	soilMoistureContent	Flotador 0 - 100	RO	Cada 1s

Al seleccionar la visualización del historial, puedes registrar los valores de tus propiedades durante un determinado periodo de tiempo y guardarlos como gráficos. Lamentablemente, solo puedes guardar los datos de 1 día en la versión gratuita de Arduino IoT Cloud.

Después de añadir todas las propiedades haga clic en EDITAR ESQUEMA. Esto abrirá el Editor Web de Arduino.

Crear boceto

Tras hacer clic en EDITAR ESQUEMA, verá que se ha creado automáticamente un nuevo esbozo.

Observe que el boceto tiene el mismo nombre que nuestra Cosa más la fecha de creación. Además de este archivo .ino, verás tres archivos más:

ReadMe.adoc: es un archivo de texto plano en el que se puede añadir información sobre el autor y el proyecto.

thingProperties.h: este archivo es generado automáticamente por Arduino IoT Cloud cuando añades propiedades a tu Thing. En general, no debes editar el código de este archivo. Se actualiza automáticamente cuando se cambian las propiedades de la cosa en el panel de control.

Por favor, consulte la página de IoT Cloud - Getting Started en el Arduino Project Hub para una explicación más detallada sobre las diferentes funciones en thingProperties.h.

Secreto: esta pestaña le permite rellenar sus credenciales de red. SECRET_SSID y SECRET_PASS son el nombre y la contraseña de la red wifi a la que se conectará el MKR1000. Después de rellenar estos datos, haga clic en guardar.

Código Arduino

Los archivos autogenerados hacen que sea bastante fácil empezar a utilizar la nube del IoT, pero, por supuesto, todavía tienes que escribir algo de código tú mismo.

En el sketch principal, por lo que no thingProperties.h, he añadido el código que leerá los sensores, controla la bomba de agua, y muestra la información en el carácter I2C LCD.

Puedes reemplazar el código en el sketch principal con el código de abajo. Conecta la placa MKR1000 a tu ordenador si aún no lo has hecho y sube el código haciendo clic en el botón de subir (flecha derecha en la parte superior de la página). Recomiendo desconectar la bomba por el momento y dejar sólo los sensores instalados.

A continuación, le explicaré cómo funciona el código y le mostraré cómo puede cambiar varios parámetros usted mismo.

Puede copiar el código haciendo clic en el botón de la esquina superior derecha del campo de código.

/*
  Sketch for automatic indoor garden project. More info: https://www.makerguides.com

  Arduino IoT Cloud Properties description

  The following variables are automatically generated and updated when changes are made to the Thing properties

  float soilMoistureContent;
  float humidity;
  float temperature;

  Properties which are marked as READ/WRITE in the Cloud Thing will also have functions
  which are called when their values are changed from the Dashboard.
  These functions are generated with the Thing and added at the end of this sketch.
*/

#include "thingProperties.h"
#include "DHT.h"
#include "LiquidCrystal_I2C.h"

#define DHTPIN A1
#define DHTTYPE DHT21

#define RELAYPIN 1
#define SOILPIN A2

DHT dht = DHT(DHTPIN, DHTTYPE);
LiquidCrystal_I2C lcd = LiquidCrystal_I2C(0x27, 20, 4);

const unsigned long pumpPeriod = 20000;
const unsigned long waitPeriod = 120000;
unsigned long previousMillis;
float moistureSensorData;

void setup() {
  // Initialize serial and wait for port to open:
  Serial.begin(9600);
  // This delay gives the chance to wait for a Serial Monitor without blocking if none is found
  delay(1500);

  // Defined in thingProperties.h
  initProperties();

  // Connect to Arduino IoT Cloud
  ArduinoCloud.begin(ArduinoIoTPreferredConnection);

  /*
     The following function allows you to obtain more information
     related to the state of network and IoT Cloud connection and errors
     the higher number the more granular information you’ll get.
     The default is 0 (only errors).
     Maximum is 4
  */
  setDebugMessageLevel(4);
  ArduinoCloud.printDebugInfo();

  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(RELAYPIN, OUTPUT);

  dht.begin();

  lcd.init();
  lcd.backlight();
}

void loop() {
  ArduinoCloud.update();

  // Your code here
  temperature = dht.readTemperature();
  humidity = dht.readHumidity();

  lcd.setCursor(0, 0);
  lcd.print("Temperature:");
  lcd.setCursor(13, 0);
  lcd.print(temperature);
  lcd.print("\xDf" "C");
  lcd.setCursor(0, 1);
  lcd.print("Humidity:");
  lcd.setCursor(10, 1);
  lcd.print(humidity);
  lcd.print("%");

  moistureSensorData = analogRead(SOILPIN);
  //Serial.println(moistureSensorData);
  soilMoistureContent = map(moistureSensorData, 883, 469, 0, 100);
  soilMoistureContent = constrain(soilMoistureContent, 0, 100);
  lcd.setCursor(0, 2);
  lcd.print("Soil moisture:");
  lcd.setCursor(15, 2);
  lcd.print(soilMoistureContent, 0);
  lcd.print("%  ");

  if (soilMoistureContent <= 30 && millis() - previousMillis >= waitPeriod) {
    digitalWrite(RELAYPIN, HIGH);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(pumpPeriod);
    digitalWrite(RELAYPIN, LOW);
    digitalWrite(LED_BUILTIN, LOW);

    previousMillis = millis();
  }
}

Cómo funciona el código

En la sección de bucle del código, la temperatura y la humedad se leen con dht.readTemperature() y dht.readHumidity() respectivamente. Las variables temperature y humidity se añadieron automáticamente en thingProperties.h y sus valores se enviarán a la nube cada 10 segundos.

La siguiente sección del código imprime los valores en el LCD I2C.

  lcd.setCursor(0, 0);
  lcd.print("Temperatura:");
  lcd.setCursor(13, 0);
  lcd.print(temperatura);
  lcd.print("\NxDf" "C");
  lcd.setCursor(0, 1);
  lcd.print("Humedad:");
  lcd.setCursor(10, 1);
  lcd.print(humedad);
  lcd.print("%");

A continuación, se lee la salida analógica del sensor de humedad del suelo con analogRead(). Este valor se escalará a 0 y 100 % de humedad. Para calibrar el sensor, puedes imprimir los datos del sensor en el Monitor Serial. El valor 833 corresponde al valor que obtuve cuando sostuve el sensor en el aire y 469 cuando lo metí en un vaso de agua.

  moistureSensorData = analogRead(SOILPIN);
  //Serial.println(moistureSensorData);
  soilMoistureContent = map(moistureSensorData, 883, 469, 0, 100);
  soilMoistureContent = constrain(soilMoistureContent, 0, 100);
  lcd.setCursor(0, 2);
  lcd.print("Humedad del suelo:");
  lcd.setCursor(15, 2);
  lcd.print(humedadSuelo, 0);
  lcd.print("% ");

En la última sección del código, compruebo si el contenido de humedad del suelo está por debajo del 30 % y, si es así, las plantas se riegan durante un tiempo determinado. He añadido un período mínimo de espera entre los ciclos de riego para dar a la tierra algo de tiempo para absorber el agua.

  if (soilMoistureContent <= 30 && millis() - previousMillis >= waitPeriod) {
    digitalWrite(RELAYPIN, HIGH);
    digitalWrite(LED_BUILTIN, HIGH);
    delay(pumpPeriod);
    digitalWrite(RELAYPIN, LOW);
    digitalWrite(LED_BUILTIN, LOW);

    previousMillis = millis();
  }

Probablemente tendrá que ajustar los parámetros pumpPeriod y waitPeriod en la parte superior del código para adaptarse a su configuración particular.

Crear un cuadro de mando

Después de subir el código, haga clic en IR A LA NUBE IOT. Ahora haga clic en Dashboards en la parte superior de la página.

Cuando estés en esta página, haz clic en crear panel de control. Puedes añadir widgets a tu panel para mostrar valores, gráficos, etc.

Haga clic en el widget y seleccione la propiedad de enlace

Ahora seleccione la propiedad que desea mostrar.

Después de añadir varios widgets, tu panel de control debería tener un aspecto similar al siguiente:

Finalizar

En este artículo, te he mostrado cómo puedes crear un sencillo sistema de riego automático con el MKR1000 y el Arduino IoT Cloud. Espero que este tutorial haya sido útil y pueda servirte de inspiración.

En la configuración actual, el Arduino IoT Cloud sólo se utiliza para mostrar y registrar los datos del sensor. Por lo tanto, también podrías hacer esto como un sistema independiente con un Arduino Uno o similar. Personalmente, sólo quería experimentar con el Arduino IoT Cloud y ver lo difícil que era configurarlo. Fue bastante más fácil de lo que pensé y definitivamente lo usaré para otros proyectos en el futuro.

Llevo poco tiempo con este sistema y parece que funciona muy bien. Informaré dentro de un mes más o menos, una vez que lo haya probado durante un poco más de tiempo.

Una cosa que podría añadir en el futuro es un interruptor de nivel de agua para el tanque y conectarlo a un sistema de alerta por correo electrónico. Tengo miedo de olvidarme de rellenar el depósito ahora que ya no tengo que pensar en regar las plantas...

Si tiene alguna pregunta o sugerencia, deje un comentario a continuación.

Tenga en cuenta que los comentarios son retenidos por la moderación para evitar el spam.